Using FreeRTOS multi-tasking in Arduino

• Made by Phillip Stevens
• Published in Arduino, SeeedStudio, and SparkFun

ABOUT THIS PROJECT

FreeRTOS, simple, easy to use, robust, optimised for Arduino IDE. Full access to FreeRTOS capabilities, within classic Arduino environment.

• timing
• tasks
• scheduler

PROJECT INFO

Type

Protip

Difficulty

Intermediate

Estimated time

1 hour

Published

March 3, 2016

License

GPL3+

• 31,147
• 69

Respect projectI made one

BookmarkShareGive feedback

THINGS USED IN THIS PROJECT

Hardware components:

	Arduino UNO & Genuino UNO	×	1
	Arduino Yun	×	1
	Arduino Leonardo	×	1
	Arduino MICRO & Genuino MICRO	×	1
	Arduino Mega 2560 & Genuino Mega 2560	×	1
	SeeedStudio Seeeduino Lite	×	1
	SeeedStudio Seeeduino Stalker V3	×	1
	SeeedStudio Seeeduino Ethernet	×	1
	SparkFun Pro Micro - 5V/16MHz	×	1
	SparkFun RedStick	×	1
	SparkFun MicroView - OLED Arduino Module	×	1
	FreeRTOS	×	1

Software apps and online services:

Arduino IDE

STORY

The Arduino IDE and environment has many drivers and libraries available within an arms reach, but the Arduino environment is limited to just setup() andloop() and doesn't support multi-tasking effectively.

This is a simple, easy to use and robust FreeRTOS implementation that can just shim into the Arduino IDE as a Library and allow the use of the best parts of both environments, seamlessly.

Background

Most operating systems appear to allow multiple programs or threads to execute at the same time. This is called multi-tasking. In reality, each processor core can only be running a single program at any given point in time. A part of the operating system called the scheduler is responsible for deciding which program to run when, and provides the illusion of simultaneous execution by rapidly switching between each program.

The scheduler in a Real Time Operating System (RTOS) is designed to provide a predictable (normally described as deterministic) execution pattern. This is particularly interesting for embedded systems, like the Arduino devices, as embedded systems often have real time requirements.

Traditional real time schedulers, such as the scheduler used in FreeRTOS, achieve determinism by allowing the user to assign a priority to each thread of execution. The scheduler then uses the priority to know which thread of execution to run next. In FreeRTOS, a thread of execution is called a Task.

Let's get started

The easiest option is use Codebender, where Arduino FreeRTOS available as a library.

Otherwise...

Firstly in the Arduino IDE Library manager, from Version 1.6.8, look for theFreeRTOS Library under the Type: “Contributed” and the Topic: “Timing”.

Searching in Arduino Library Manager

Ensure that the most recent FreeRTOS Library Release is installed. As of writing that is v8.2.3-18.

FreeRTOS v8.2.3 Release 6 installed.

Then under the Sketch->Include Library menu, ensure that the FreeRTOS library is included in your sketch. A new empty sketch will look like this.

Empty Sketch with FreeRTOS Included.

Compile and upload this empty sketch to your Arduino Uno/Yun/Leonardo/Mega or Goldilocks 1284p device. This will show you how much of your flash is consumed by the FreeRTOS scheduler. As a guide the following information was compiled using Arduino v1.6.9 on Windows 10.

// Device:   loop() -> FreeRTOS | Additional Program Storage
// Uno:         444 ->   7340   |     21%
// Goldilocks:  502 ->   7408   |      6%
// Leonardo:   3624 ->  10508   |     24%
// Yun:        3618 ->  10502   |     24%
// Mega:        656 ->  24108   |      9%

At this stage FreeRTOS is already running on your device.

Next steps

Now upload and test the Blink sketch, with an underlying Real-Time Operating System simply by inserting #include <Arduino_FreeRTOS.h> at the start of the sketch. That’s all there is to having FreeRTOS running in your sketches.

The next step is to explore the features provided by a professional RTOS within the Arduino IDE.

Blink_AnalogRead.ino is a good way to start off as it combines two basic Arduino examples, Blink and AnalogRead into one sketch with two separate Tasks. Both Tasks perform their duties, managed by the FreeRTOS scheduler. This sketch can be found in the Examples Folder of the Arduino IDE.

If you're interested in low power or battery applications, it is easy to use FreeRTOS to support the AVR ATmega power reduction modes.

Later articles will cover the use of Semaphores to protect hardware resources (like the Serial port), Queues to transfer data between Tasks, or Timers to manage exact delays and timeouts. The FreeRTOS Getting Started page has lots of further information on how to use the advanced features, and providesDemonstration Examples. Also many more AVR FreeRTOS example applicationsare available, that can be simply converted to use the Arduino environment.

CODE

Blink_AnalogRead.inoArduino

These are two basic sketches from the Arduino IDE Built-in Examples, combined into one multi-tasking sketch using two FreeRTOS Tasks.

#include <Arduino_FreeRTOS.h>

// define two tasks for Blink & AnalogRead
void TaskBlink( void *pvParameters );
void TaskAnalogRead( void *pvParameters );

// the setup function runs once when you press reset or power the board
void setup() {

  // Now set up two tasks to run independently.
  xTaskCreate(
    TaskBlink
    ,  (const portCHAR *)"Blink"   // A name just for humans
    ,  128  // Stack size
    ,  NULL
    ,  2  // priority
    ,  NULL );

  xTaskCreate(
    TaskAnalogRead
    ,  (const portCHAR *) "AnalogRead"
    ,  128 // This stack size can be checked & adjusted by reading Highwater
    ,  NULL
    ,  1  // priority
    ,  NULL );

  // Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

void loop()
{
  // Empty. Things are done in Tasks.
}

/*--------------------------------------------------*/
/*---------------------- Tasks ---------------------*/
/*--------------------------------------------------*/

void TaskBlink(void *pvParameters)  // This is a task.
{
  (void) pvParameters;

  // initialize digital pin 13 as an output.
  pinMode(13, OUTPUT);

  for (;;) // A Task shall never return or exit.
  {
    digitalWrite(13, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(13, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
}

void TaskAnalogRead(void *pvParameters)  // This is a task.
{
  (void) pvParameters;

  // initialize serial communication at 9600 bits per second:
  Serial.begin(9600);

  for (;;)
  {
    // read the input on analog pin 0:
    int sensorValue = analogRead(A0);
    // print out the value you read:
    Serial.println(sensorValue);
    vTaskDelay(1);  // one tick delay (15ms) in between reads for stability
  }
}

CREDITS

Phillip Stevens

You can flog a dead horse to water, but the grass is always greener on the flip side.

FollowContact

Thanks to Richard Berry.

REPLICATIONS

Did you replicate this project? Share it!

I made one

Love this project? Think it could be improved? Tell us what you think!